下载与安装 [复制链接]
电梯直达
复制

secowu

Rank: 7 Rank: 7 Rank: 7

UID: 10033
帖子: 1319
PB币: 3167
贡献: 0
技术: 4
活跃: 830

41^F

发表于 2019-4-26 23:39:54 IP属地广东 |只看该作者

@echo off
rem author : 默然King
title Office 2019 专业增强版下载安装脚本
cd /d "%~dp0"
color 1f
set Source=
echo.
echo ---------------------------------------------------------
echo 请选择产品授权通道
echo ---------------------------------------------------------
echo 1=零售版 Retail
echo 2=批量授权 Volume
echo 3=退出脚本
echo ---------------------------------------------------------
echo.
choice /n /c 123 /m "请选择"
if errorlevel==3 exit
if errorlevel==2 set "Product=Volume" && goto :Menu
if errorlevel==1 set "Product=Retail" && goto :Menu
:Menu
cls & echo.
echo ---------------------------------------------------------
echo 请选择任务
echo ---------------------------------------------------------
echo 1=在线安装 Office 2019
echo 2=离线安装 Office 2019
echo 3=在线安装 Office 2019 并保留安装文件
echo 4=下载 Office 2019 安装文件
echo 5=退出脚本
echo ---------------------------------------------------------
echo.
choice /n /c 12345 /m "请选择"
if errorlevel==5 exit
if errorlevel==4 goto :Download
if errorlevel==3 goto :Online
if errorlevel==2 goto :Offline
if errorlevel==1 goto :Install
:Install
cls & echo.
if /i "%PROCESSOR_IDENTIFIER:~0,3%"=="x86" (
set "bit=32"
goto :StartI
)
echo ---------------------------------------------------------
echo 请选择需要安装的版本
echo ---------------------------------------------------------
echo 1=X64
echo 2=X86
echo 3=退出脚本
echo ---------------------------------------------------------
echo.
choice /n /c 123 /m "请选择"
if errorlevel==3 exit
if errorlevel==2 set "bit=32" && goto :StartI
if errorlevel==1 set "bit=64" && goto :StartI
:StartI
cls & echo.
echo ---------------------------------------------------------
echo 正在安装 Office 2019 专业增强版 %bit% 位版本，请等待完成。
echo ---------------------------------------------------------
call :Config
"%~dp0setup.exe" /configure "%~dp0configuration.xml" || goto :Error
goto :Close
:Offline
cls & echo.
echo ---------------------------------------------------------
set /p "Source=请输入 Office 安装文件路径，路径中不包含引号。(即使路径中包含空格):"
goto :Install
:Download
cls & echo.
set "Source=%cd%"
echo ---------------------------------------------------------
echo 请选择需要下载的版本
echo ---------------------------------------------------------
echo 1=X64
echo 2=X86
echo 3=退出脚本
echo ---------------------------------------------------------
echo.
choice /n /c 123 /m "请选择"
if errorlevel==3 exit
if errorlevel==2 set "bit=32" && goto :StartD
if errorlevel==1 set "bit=64" && goto :StartD
:StartD
cls & echo.
echo ---------------------------------------------------------
echo 正在下载 Office 2019 %bit% 位版本，请等待完成。
echo ---------------------------------------------------------
call :Config
"%~dp0setup.exe" /download "%~dp0configuration.xml" || goto :Null
goto :end
:Online
cls & echo.
set "Source=%cd%"
if /i "%PROCESSOR_IDENTIFIER:~0,3%"=="x86" (
set "bit=32"
goto :Start
)
echo ---------------------------------------------------------
echo 请选择需要安装的版本
echo ---------------------------------------------------------
echo 1=X64
echo 2=X86
echo 3=退出脚本
echo ---------------------------------------------------------
echo.
choice /n /c 123 /m "请选择"
if errorlevel==3 exit
if errorlevel==2 set "bit=32" && goto :Start
if errorlevel==1 set "bit=64" && goto :Start
:Start
cls & echo.
echo ---------------------------------------------------------
echo 正在安装 Office 2019 专业增强版 %bit% 位版本，请等待完成。
echo ---------------------------------------------------------
call :Config
"%~dp0setup.exe" /download "%~dp0configuration.xml" || goto :Null
"%~dp0setup.exe" /configure "%~dp0configuration.xml" || goto :Error
goto :Close
:Close
cls & echo.
echo ---------------------------------------------------------
echo Office 2019 安装完成，按任意键退出!
echo ---------------------------------------------------------
pause >nul
del /s /q configuration.xml >nul 2>nul
exit
:end
cls & echo.
echo ---------------------------------------------------------
echo 下载完成， Office 2019 安装文件已保存在： "%Source%" 目录。
echo 按任意键退出!
echo ---------------------------------------------------------
pause >nul
del /s /q configuration.xml >nul 2>nul
exit
:Error
cls & echo.
echo ---------------------------------------------------------
echo Office 2019 安装失败，按任意键退出脚本！
echo ---------------------------------------------------------
pause >nul
del /s /q configuration.xml >nul 2>nul
exit
:Null
cls & echo.
echo ---------------------------------------------------------
echo Office 2019 下载失败，按任意键退出脚本！
echo ---------------------------------------------------------
pause >nul
del /s /q configuration.xml >nul 2>nul
exit
:Config
del /s /q configuration.xml >nul 2>nul
rem 下面是配置脚本，若要下载其它版本/组件/语言，请自行编辑下面的内容。
rem 参考网页: https://docs.microsoft.com/en-us/deployoffice/configuration-options-for-the-office-2016-deployment-tool
> "%~dp0configuration.xml" (
echo ^<Configuration^>
echo ^<Add SourcePath="%Source%" OfficeClientEdition="%bit%"^>
echo ^<Product ID="ProPlus2019%Product%"^>
echo ^<Display AcceptEULA="TRUE" /^>
echo ^<Language ID="zh-cn" /^>
echo ^<Language ID="zh-tw" /^>
echo ^<Language ID="en-us" /^>
echo ^</Product^>
echo ^<Product ID="ProjectPro2019Volume"^>
echo ^<Language ID="zh-CN" /^>
echo ^<Language ID="zh-tw" /^>
echo ^<Language ID="en-us" /^>
echo ^<ExcludeApp ID="OneDrive" /^>
echo ^</Product^>
echo ^<Product ID="VisioPro2019Volume"^>
echo ^<Language ID="zh-CN" /^>
echo ^<Language ID="zh-tw" /^>
echo ^<Language ID="en-us" /^>
echo ^<ExcludeApp ID="OneDrive" /^>
echo ^</Product^>
echo ^</Add^>
echo ^</Configuration^>
echo.
)
goto :eof
rem echo ^<ExcludeApp ID="Access" /^>
rem echo ^<ExcludeApp ID="Groove" /^>
rem echo ^<ExcludeApp ID="OneDrive" /^>
rem echo ^<ExcludeApp ID="InfoPath" /^>
rem echo ^<ExcludeApp ID="Lync" /^>
rem echo ^<ExcludeApp ID="Outlook" /^>
rem echo ^<ExcludeApp ID="Project" /^>
rem echo ^<ExcludeApp ID="Publisher" /^>
rem echo ^<ExcludeApp ID="SharePointDesigner" /^>

复制代码

okxing okxing 当前离线积分 33 最后登录 2022-4-13 精华 0 阅读权限 0 主题 1 UID 542032 帖子 83 PB币 8 威望 0 贡献 0 技术 0 活跃 479 发消息头像被屏蔽 UID 542032 帖子 83 PB币 8 贡献 0 技术 0 活跃 479 串个门加好友打招呼发消息	42^F 发表于 2019-4-27 10:04:51 IP属地江西 \|只看该作者提示: 作者被禁止或删除内容自动屏蔽