补丁安装批处 [复制链接]

372065027

Rank: 1

UID: 3101727
帖子: 6
PB币: 39
贡献: 0
技术: 25
活跃: 3

发表于 2012-12-29 20:19:03 IP属地贵州 |显示全部楼层

本帖最后由 372065027 于 2012-12-29 20:22 编辑

@echo off
:: hnfeng 20120516
:: ◆自动运行文件夹里面所有系统补丁程序并显示总进度及正在安装的程序名◆
:: ================================
cd /d "%~dp0"&color 3E&mode con lines=15 &title 补丁包批处理安装程序〔win7〕
ver | find "6.1" > NUL && (set XT=Windows7&set CX=Windows6.1-KB*.msu&set CS=/quiet /norestart&goto TOP)
ver | find "6.1" > NUL && (set XT=Windows7&set CX=*.exe&set CS=/quiet /norestart&goto TOP)
ver | find "5.1" > NUL && (set XT=WindowsXP&set CX=WindowsXP-KB*.exe&set CS=/quiet /norestart /nobackup&goto TOP)
ver | find "5.0" > NUL && (set XT=Windows2000&set CX=Windows2000-KB*.exe&set CS=/quiet /norestart /nobackup&goto TOP)
ver | find "5.2" > NUL && (set XT=Windows2003&set CX=WindowsServer2003-KB*.exe&set CS=/quiet /norestart /nobackup&goto TOP)
ver | find "6.0" > NUL && (set XT=WindowsVista&set CX=Windows6.0-KB*.msu&set CS=/quiet /norestart&goto TOP)
:: ================================
:TOP
set title=%XT% 补丁包批处理安装程序〔win7〕
title %title%
set work=0&set n=0&set mo=0&set number=0&set hotfix=
if not exist %CX% echo.&echo.&echo 没找到补丁程序，按任意键退出 ...&echo.&echo.&echo (该批处理应该在系统补丁程序所在文件夹里运行.)&pause>nul&exit
set k=▏&set kn=0
:Kong
if %kn% LSS 33 (set k=%k%　&set /a kn=%kn%+1&goto Kong)
for /F %%s in ('dir /b /a-d %CX% ^| find /v /c ""') do set all=%%s
for /F %%i in ('dir /b /a-d /OD %CX%') do (set hotfix=%%i&call :show)
set hotfix=&call :show
goto end
:show
:check
if %number% GTR %mo% set num=%num%█&set /a mo=%mo%+1&set k=%k:~0,-1%&goto check

mode con: cols=83 lines=16 &color 22
cls&echo.&echo.
if "%hotfix%"=="" (echo    %title% ) else (echo    正在安装：%hotfix% ...)
echo                                                          进度： %n% / %all%
echo.&echo                                  已经完成 %work% %%%
echo    ┌──────────────────────────────────┐
echo    │%num%%k%│&echo    │%num%%k%│&echo    │%num%%k%│
echo    └──────────────────────────────────┘
echo.
if not "%hotfix%"=="" echo  hnfeng.2012.5
if %work%==100 goto :EOF
::ping 127.1 -n 2 >nul
%hotfix% %CS%
set /a n=%n%+1
set /a work=(%n%)*100/(%all%)
set /a number=%work%/3
set /a number=%number%+1
goto :EOF
:end
echo    运行完成，请按任意键退出... （建议重新启动系统）
pause>nul&exit

附件: 你需要登录才可以下载或查看附件。没有帐号？注册

2 查看全部评分